No entry to set "max-line-length" key for formatting in Godot addon settings... And question about .editorconfig

[DexArson]

There is a "Lint Line Length" in addon settings menu which only affects linting. I read plugin.gd and found it was implemented by run the formatter executable with --max-line-length=<max_line_length> flag:

func lint_code(script: GDScript) -> Array:
    # ...
    var formatter_arguments: Array = ["lint", ProjectSettings.globalize_path(script_path)]

    var max_line_length := get_editor_setting(SETTING_LINT_LINE_LENGTH) as int
    formatter_arguments.append("--max-line-length")
    formatter_arguments.append(str(max_line_length))
    # ...
    var exit_code := OS.execute(get_editor_setting(SETTING_FORMATTER_PATH), formatter_arguments, output)
    # ...

However for format_code function there is no line to add --max-line-length flag. This flag is valid for the executable itself for formatting, and line length is always a important attribute for a formatter, so it's weird the addon settings doesn't have any entry to set it, and it's quite easy to implement it by adding same codes to the format code function. I did so to let Lint Line Length value also affects formatting, and it works fine for me.

Besides .editorconfig file seems not work with addon. I tried formatting gdscript files with formatter executable directly using command lines in terminal, and it can find and use parameters in editor config file in parent directory correctly. So it's also weird that it doesn't work with addon. According to plugin.gd:

func get_editorconfig_format_on_save(script_path: String) -> Variant:
    var editorconfig_path := ProjectSettings.globalize_path("res://.editorconfig")
    # ...

Seems that it will only try to find editor config file in project root, and it only reads gdscript_formatter_format_on_save parameter from that file, ignoring other parameters. Is it intended?

EDIT:

Just quickly inspected plugin.gd again. Found why it ignores the .editorconfig. When you use the addon in godot editor, it creates a temp file in elsewhere:

	var path_temporary_file := OS.get_temp_dir().path_join(
		"gdscript_formatter_%d.gd" % Time.get_ticks_msec()
	)

The addon will first formats the temp file, then replaces the actual file with it. For my system it creates the temp file in somewhere like c:/temp/, far away from my project directory. When use the executable to format it, it will only search through the temp file folder and temp file's parent folders for .editorconfig. That's why it can't find my project's .editorconfig.

So one of the simplest solutions is just create the temp file in the same folder with the original file you want to format, and it's also easy to implement. Since I'm busy now I may try this method when I have some free time.

[VIxeny]

I have the same issue. The addon also ignores the .editorconfig file. However, if I use the formatter from the terminal, everything works fine.

I also think it would be nice to add a Max Line Length setting above Lint Line Length in the editor settings.

Could you send me the code that makes the Lint Line Length value also affect formatting and tell me where I should paste it?

[DexArson]

Could you send me the code that makes the Lint Line Length value also affect formatting and tell me where I should paste it?

Sure!

In plugin.gd, find the var formatter_arguments := PackedStringArray() line in format_code(), and paste codes I mentioned above after it. After that this function should look like this:

func format_code(script: GDScript, force_reorder := false, source_content: Variant = null) -> String:
	var script_path := script.resource_path
	if source_content == null and script_path.is_empty():
		push_error("GDScript Formatter Error: Can't format an unsaved script.")
		return ""

	# Source content is not set, read from the GDScript resource instead.
	#
	# This is a bit of a hack to avoid two issues:
	#
	# 1. Running GDScript formatter on stdin/stdout through Godot with
	# OS.execute() has encoding issues with UTF-8 characters and we don't have
	# control over the output encoding (it might be assuming ASCII characters)
	#
	# 2. If we modify a file in place using the external formatter from Godot,
	# it will bring up a pop-up that warns users that the file has been changed
	# outside Godot.
	#
	# To work around that, I save a copy of the script as a temporary file,
	# format the file, and read it specifically as a UTF-8 string.
	if source_content == null:
		var source_file := FileAccess.open(
			ProjectSettings.globalize_path(script_path),
			FileAccess.READ,
		)
		if not source_file:
			push_error("GDScript Formatter Error: Cannot read source file: " + script_path)
			return ""

		# FileAccess.get_as_text() reads the file as UTF-8. We use it here and after
		# formatting the temporary file.
		source_content = source_file.get_as_text()
		source_file.close()

	var path_temporary_file := OS.get_temp_dir().path_join(
		"gdscript_formatter_%d.gd" % Time.get_ticks_msec()
	)
	var temporary_file := FileAccess.open(path_temporary_file, FileAccess.WRITE)
	if temporary_file == null:
		push_error("GDScript Formatter Error: Cannot create temporary file: " + path_temporary_file)
		return ""
	temporary_file.store_string(source_content as String)
	temporary_file.close()

	var formatter_arguments := PackedStringArray()
	
	# PASTE HERE!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
	var max_line_length := get_editor_setting(SETTING_LINT_LINE_LENGTH) as int
	formatter_arguments.append("--max-line-length")
	formatter_arguments.append(str(max_line_length))
	# !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
	
	if get_editor_setting(SETTING_USE_SPACES):
		formatter_arguments.push_back("--use-spaces")
		formatter_arguments.push_back("--indent-size=%d" % get_editor_setting(SETTING_INDENT_SIZE))

	var format_mode := get_format_mode()
	var should_reorder := force_reorder or format_mode == FormatMode.REORDER_CODE

	if should_reorder:
		formatter_arguments.push_back("--reorder-code")

	if not force_reorder and format_mode == FormatMode.VERIFY_STRUCTURE:
		# NB: this is a deprecated flag, replaced with --verify-structure, but
		# we keep it here for users that have a previous version of the
		# formatter installed.
		formatter_arguments.push_back("--safe")

	formatter_arguments.push_back(path_temporary_file)

	var output: Array = []
	var exit_code := OS.execute(
		get_editor_setting(SETTING_FORMATTER_PATH),
		formatter_arguments,
		output,
		true,
	)

	var formatted_content := ""
	if exit_code == OK:
		var result_file := FileAccess.open(path_temporary_file, FileAccess.READ)
		if result_file:
			formatted_content = result_file.get_as_text()
			result_file.close()
		else:
			push_error("Format GDScript: Cannot read formatted output from temp file")
	else:
		push_error(
			"Format GDScript failed: "
			+ (script_path if not script_path.is_empty() else "unsaved script")
		)
		push_error(
			"\tExit code: " + str(exit_code) + " Output: "
			+ (output[0].strip_edges() if output.size() > 0 else "No output"),
		)
		push_error(
			'\tIf your script does not have any syntax errors, this might be a formatter bug.'
		)

	if FileAccess.file_exists(path_temporary_file):
		DirAccess.remove_absolute(path_temporary_file)

	return formatted_content