build.zig

const std = @import("std");

pub fn build(b: *std.Build) void {
    const target = b.standardTargetOptions(.{});
    const optimize = b.standardOptimizeOption(.{});

    // Parse version from build.zig.zon
    const zon_raw = b.build_root.handle.readFileAlloc(
        b.graph.io,
        "build.zig.zon",
        b.allocator,
        .limited(65536),
    ) catch @panic("failed to read build.zig.zon");
    defer b.allocator.free(zon_raw);

    // fromSliceAlloc needs [:0]const u8; grow by one byte and add
    // the sentinel ourselves rather than thread a fixed buffer.
    const zon_buf = b.allocator.realloc(zon_raw, zon_raw.len + 1) catch
        @panic("OOM growing build.zig.zon buffer");
    defer b.allocator.free(zon_buf);
    zon_buf[zon_raw.len] = 0;
    const zon_src: [:0]const u8 = zon_buf[0..zon_raw.len :0];

    const Zon = struct {
        name: enum { watch },
        fingerprint: u64,
        version: []const u8,
        minimum_zig_version: []const u8,
        dependencies: struct {
            ghostty: struct { url: []const u8, hash: []const u8 },
        },
        paths: []const []const u8,
    };
    const zon = std.zon.parse.fromSliceAlloc(
        Zon,
        b.allocator,
        zon_src,
        null,
        .{},
    ) catch @panic("failed to parse build.zig.zon");

    const build_options = b.addOptions();
    build_options.addOption([]const u8, "version", zon.version);

    const exe_mod = b.createModule(.{
        .root_source_file = b.path("src/main.zig"),
        .target = target,
        .optimize = optimize,
    });
    exe_mod.addImport("build_options", build_options.createModule());

    if (b.lazyDependency("ghostty", .{})) |dep| {
        exe_mod.addImport("ghostty-vt", dep.module("ghostty-vt"));
    }

    const exe = b.addExecutable(.{
        .name = "watch",
        .root_module = exe_mod,
    });

    b.installArtifact(exe);

    const run_cmd = b.addRunArtifact(exe);
    run_cmd.step.dependOn(b.getInstallStep());
    if (b.args) |args| {
        run_cmd.addArgs(args);
    }

    const run_step = b.step("run", "Run the app");
    run_step.dependOn(&run_cmd.step);

    const exe_unit_tests = b.addTest(.{
        .root_module = exe_mod,
    });
    const run_exe_unit_tests = b.addRunArtifact(exe_unit_tests);
    const test_step = b.step("test", "Run unit tests");
    test_step.dependOn(&run_exe_unit_tests.step);
}