Allow static, non-framework iOS builds

An iOS app can only load a signed framework, so a shared Python has to be built
as one. A static libpython is linked into the app binary and loads nothing at
runtime, so the requirement does not apply to it, but configure refused that
configuration outright.

Refuse it only where it cannot work: a shared build with no framework. The
LINKFORSHARED and MODULE_DEPS_SHARED framework references are gated on
enable_framework, as the Darwin arm above already does, since a build without a
framework has nothing to link against. Passing no framework option at all still
errors, so a non-framework build stays an explicit opt-in.

Author: clementperon

configure

@@ -579,7 +579,6 @@ AC_ARG_ENABLE([framework],
 	case $enableval in
 	no)
 		case $ac_sys_system in
-			iOS) AC_MSG_ERROR([iOS builds must use --enable-framework]) ;;
 			*)
 				PYTHONFRAMEWORK=
 				PYTHONFRAMEWORKDIR=no-framework
@@ -689,7 +688,7 @@ AC_ARG_ENABLE([framework],
 		esac
 	],[
 	case $ac_sys_system in
-		iOS) AC_MSG_ERROR([iOS builds must use --enable-framework]) ;;
+		iOS) AC_MSG_ERROR([iOS builds must use --enable-framework, or --disable-framework with --disable-shared to build a static libpython]) ;;
 		*)
 			PYTHONFRAMEWORK=
 			PYTHONFRAMEWORKDIR=no-framework
@@ -1689,6 +1688,12 @@ else # shared is disabled
 fi
 AC_MSG_RESULT([$LDLIBRARY])
 
+# A shared Python on iOS has to be a framework: an app can only load a signed
+# framework, never a bare dylib. A static libpython has nothing to load.
+if test "$ac_sys_system" = "iOS" && test "$PY_ENABLE_SHARED" = 1 && test -z "$PYTHONFRAMEWORK"; then
+  AC_MSG_ERROR([iOS builds must use --enable-framework, or --disable-framework with --disable-shared to build a static libpython])
+fi
+
 # HOSTRUNNER - Program to run CPython for the host platform
 AC_MSG_CHECKING([HOSTRUNNER])
 if test -z "$HOSTRUNNER"
@@ -3830,7 +3835,11 @@ then
 			fi
 			LINKFORSHARED="$LINKFORSHARED"
 		elif test $ac_sys_system = "iOS"; then
-			LINKFORSHARED="-Wl,-stack_size,$stack_size $LINKFORSHARED "'$(PYTHONFRAMEWORKDIR)/$(PYTHONFRAMEWORK)'
+			LINKFORSHARED="-Wl,-stack_size,$stack_size $LINKFORSHARED"
+
+			if test "$enable_framework"; then
+				LINKFORSHARED="$LINKFORSHARED "'$(PYTHONFRAMEWORKDIR)/$(PYTHONFRAMEWORK)'
+			fi
 		fi
 		;;
 	OpenUNIX*|UnixWare*) LINKFORSHARED="-Wl,-Bexport";;
@@ -6755,8 +6764,9 @@ if test "$PY_ENABLE_SHARED" = "1" && ( test -n "$ANDROID_API_LEVEL" || test "$MA
   LIBPYTHON="-lpython${VERSION}${ABIFLAGS}"
 fi
 
-# On iOS the shared libraries must be linked with the Python framework
-if test "$ac_sys_system" = "iOS"; then
+# On iOS the shared libraries must be linked with the Python framework, when one
+# is being built
+if test "$ac_sys_system" = "iOS" && test "$enable_framework"; then
   MODULE_DEPS_SHARED="$MODULE_DEPS_SHARED \$(PYTHONFRAMEWORKDIR)/\$(PYTHONFRAMEWORK)"
 fi